get — Retrieve a property value from a graphics entity or an User Interface object.
h=get(prop) val=get(h,prop) val=h.prop
handle, the handle of the entity to retrieve a property.
h can be a vector of handles, in which case get returns
the property value for all objects contained in h. h can also be 0 to get the root object properties.
character string name of the property.
value of the property.
This routine can be used to retrieve the value of a specified property from a
graphics entity or a GUI object. In this case it is equivalent to use the dot operator on an handle.
For exemple, get(h,"background") is equivalent to h.background.
Property names are character strings. To get the list of all existing properties see graphics_entities or uicontrol for User Interface objects.
get function can be also called with only a property as argument. In this case,
the property must be one of the following:
returns a handle on the lastly created (and still
existent) entity.
get('current_entity') and get('hdl') are equivalent to gce.
returns a handle on the current graphic figure.
get('current_figure') is equivalent to gcf.
returns a handle on the current axes entity.
get('current_axes') is equivalent to gca.
returns a handle on the default figure entity.
get('default_figure') is equivalent to gdf.
returns a handle on the default axes entity.
get('default_axes') is equivalent to gda.
returns a row vector containing ids of all opened graphic figures.
get('figures_id') is equivalent to winsid.
// for graphics entities
clf()
// simple graphics objects
subplot(121);
x=[-.2:0.1:2*%pi]';
plot2d(x-2,x.^2);
subplot(122);
xrect(.2,.7,.5,.2);
xrect(.3,.8,.3,.2);
xfarc(.25,.55,.1,.15,0,64*360);
xfarc(.55,.55,.1,.15,0,64*360);
xstring(0.2,.9,"Example <<A CAR>>");
h=get("current_entity") //get the newly object created
h.font_size=3;
f=get("current_figure") //get the current figure
f.figure_size
f.figure_size=[700 500];
f.children
f.children(2).type
f.children(2).children
f.children(2).children.children.thickness=4;
a=get("current_axes") //get the current axes
a.children.type
a.children.foreground //get the foreground color of a set of graphics objects
a.children.foreground=9;
// for User Interface objects
h=uicontrol('string', 'Button'); // Opens a window with a button.
p=get(h,'position'); // get the geometric aspect of the button
disp('Button width: ' + string(p(3))); // print the width of the button
close(); // close figure